Datamining and linking

Using the Regular Expression Tester below, create regular expressions for the following tasks:

• Two words, e.g., "hosted by"
• A species name, e.g., Homo sapiens
• A species name with a subgenus, e.g., Varanus (Euprepiosaurus) rainerguentheri
• A museum specimen code, e.g. "USNM 100895"
• A latitude, e.g. 10°02'N (remember to handle both the northern and southern hemispheres)

Start an Open Refine session and go to http://127.0.0.1:3333.

Save the names below to a text file and open it as a new project.

Names
Achatina fulica (giant African snail)
Acromyrmex octospinosus ST040116-01
Alepocephalus bairdii (Baird's smooth-head)
Alaska Sea otter (Enhydra lutris kenyoni)
Toxoplasma gondii
Leucoagaricus gongylophorus
Pinnotheres
Themisto gaudichaudii
Hyperiidae

You should see something like this:

Click on the column header Names and choose Reconcile → Start reconciling.

A dialog will popup asking you to select a service.

If you've already added a service it will be in the list on the left. If not, click the Add Standard Services... button at the bottom left and paste in the URL (in this case https://observant-skull.glitch.me).

Once the service has loaded click on Start Reconciling. Once it has finished you should see most of the names linked to GBIF (click on a name to check this):

Sometimes there may be more than one possible match, in which case these will be listed in the cell. Once you have reconciled the data you may want to do something with the reconciliation. For example, if you want to get the ids for the names you've just matched you can create a new column based on the reconciliation. Click on the Names column header and choose Edit column → Add column based on this column.... A dialog box will be displayed:

In the box labelled Expression enter cell.recon.match.id and give the column a name (e.g., "ID"). You will now have a column of ids for the names:

You could also get the names extracted by creating a column based on the values of cell.recon.match.name. To compare this with the original values, click on the Names column header and choose Reconcile → Actions → Clear reconciliation data. Now you can see the original input names, and the string extracted from each name:

IUCN status

SELECT * WHERE 
{ 
  ?wikidata wdt:P141 ?status. 
  ?wikidata rdfs:label ?name .
  ?wikidata wdt:P225 ?taxon_name .
  ?status rdfs:label ?status_label .
  FILTER (lang(?name) = 'en') .
  FILTER (lang(?status_label) = 'en')
}
LIMIT 10

Taxa that have been sequenced

SELECT *
WHERE
{
  # taxon 
  ?taxon wdt:P31 wd:Q16521 .
  ?taxon wdt:P225 ?name . # taxonomic name
  ?taxon wdt:P685 ?ncbi .
}
limit 100

Maps for Hominidae

SELECT ?child_name ?map 
WHERE
{
 VALUES ?root_name {"Hominidae"}
 ?root wdt:P225 ?root_name .
 ?child wdt:P171+ ?root .
 ?child wdt:P171 ?parent .
 ?child wdt:P225 ?child_name .
 ?parent wdt:P225 ?parent_name .
 ?child wdt:P181 ?map . 
}
limit 100

Distribution maps

SELECT *
WHERE
{
  # taxon 
  ?taxon wdt:P31 wd:Q16521 .
  ?taxon wdt:P181 ?map .
}
limit 100

Publications describing new species

SELECT *
WHERE
{
  # taxon published in
  ?taxon wdt:P5326 ?work .
  ?work rdfs:label ?work_name .
  ?taxon rdfs:label ?name .
  FILTER (lang(?name) = 'en') .
  FILTER (lang(?work_name) = 'en') .
}
limit 100

Species hosted by the potato

SELECT *
WHERE
{
  # taxon 
  ?taxon wdt:P225 "Solanum tuberosum" .
  ?parasite wdt:P2975 ?taxon .
  ?parasite wdt:P225 ?parasite_name . 

}

Host associations

SELECT *
WHERE
{
  # taxon 
  ?taxon wdt:P31 wd:Q16521 .
  ?taxon wdt:P225 ?name . # taxonomic name
  ?taxon wdt:P2975 ?host .
  ?host wdt:P225 ?host_name . # taxonomic name of host
}
limit 100

Food source for sperm whale

SELECT *
WHERE
{
  # taxon 
  ?taxon wdt:P225 "Physeter macrocephalus" .
  ?taxon wdt:P1034  ?food .
  ?food rdfs:label ?food_label . 
  
  FILTER (lang(?food_label) = 'en') .
}

Food sources for different species

SELECT *
WHERE
{
  # taxon 
  ?taxon wdt:P31 wd:Q16521 .
  ?taxon wdt:P225 ?name  .
  # food source
  ?taxon wdt:P1034  ?food .
  ?food rdfs:label ?food_label . 
  
  FILTER (lang(?food_label) = 'en') .
 
}
limit 100